A LANGUAGE FOR DIGITAL DESIGN

[Thomas Klemm]

Here are the equivalent programs for the HP-42S.
A slightly different data-format is used though: s.tttttt

s: signal on (1) or off (0)
tttttt: time in ns

Digital logic simulator

Code:

00 { 55-Byte Prgm }
01▸LBL "_"
02 FP
03 1
04 LASTX
05 IP
06 -
07 +
08 RTN
09▸LBL "and"
10 FP
11 X<>Y
12 LASTX
13 X<>Y
14 AND
15 X<>Y
16 LASTX
17 FP
18 X>Y?
19 X<>Y
20 R↓
21 +
22 RTN
23▸LBL "or"
24 XEQ "_"
25 X<>Y
26 XEQ "_"
27 XEQ "and"
28 XEQ "_"
29 END

Technology

Code:

00 { 91-Byte Prgm }
01▸LBL "2AND_"
02 XEQ "and"
03 XEQ "_"
04 9ᴇ-6
05 +
06 RTN
07▸LBL "3OR"
08 STO 00
09 R↓
10 XEQ "or"
11 RCL 00
12 XEQ "or"
13 3ᴇ-5
14 +
15 RTN
16▸LBL "2XOR"
17 STO 00
18 XEQ "_"
19 X<>Y
20 STO 01
21 XEQ "and"
22 STO 02
23 RCL 00
24 RCL 01
25 XEQ "_"
26 XEQ "and"
27 RCL 02
28 XEQ "or"
29 35ᴇ-6
30 +
31 END

Logic equations

Code:

00 { 54-Byte Prgm }
01▸LBL "ENB_"
02 RCL "A"
03 RCL "B"
04 XEQ "2XOR"
05 RTN
06▸LBL "XY"
07 XEQ "ENB_"
08 RCL "C"
09 XEQ "2AND_"
10 RCL "A"
11 RCL "B"
12 XEQ "3OR"
13 END

Examples

0.000000
STO "A"

0.000010
STO "B"

1.000010
STO "C"

XEQ "ENB_"
0.000045

XEQ "XY"
1.000084

Cheers
Thomas