Post Reply 
HP Prime: Black Hole Characteristics – Hawking Radiation
01-05-2018, 03:32 AM (This post was last modified: 01-23-2018 03:02 PM by Eddie W. Shore.)
Post: #1
HP Prime: Black Hole Characteristics – Hawking Radiation
HP Prime: Black Hole Characteristics – Hawking Radiation

Equations Used

Given the mass (either in kg or solar masses), the following equations can estimate these black hole characteristics:

Swartzchild Radius (in m):
R = M * G/c^2

Life time left as the black hole slowly radiates (in s):
t = M^3 * 5120 * π * G^2 / (hbar * c^4)

The HP Prime uses the conversion for seconds to years:
1 year ≈ 31556925.9747 s

Average temperature of the black hole (K):
temp = (hbar * c^3)/(M * 8 * k * π * G)

If you need to convert to °C subtract 273.15 from this result.

Surface area of the black hole (m^2):
sa = (M^2 * 16 * π * G^2)/c^4

Surface gravity of the black hole (m/s^2), as you can imagine, this will be a huge number:
gr = c^4 / (M * 4 * G)

Constants Used

Values are taken from the HP Prime

Universal Gravitation Constant
G = 6.67384 * 10^-11 m^3/(kg * s^2)

Speed of Light
c = 299792458 m/s

Plank Constant Divided by 2*π
hbar = 1.054571726 * 10^-34 J*s

Boltzmann Constant
k = 1.3806488 * 10^-23 J/K



HP Prime Program BLACKHOLE

Code:
EXPORT BLACKHOLE()
BEGIN
// EWS 2018-01-04
// Hawking Radiation

// Input of mass
LOCAL ch,M;
INPUT({M,{ch,{"kg","Solar Mass"}}},
"Mass",{"Mass: ","Unit: "});

IF ch=2 THEN
M:=1.988435ᴇ30*M;

END;

LOCAL k,G,c,hbar;
// from 4 Constants
// Shift, Units, Constant
k:=1.3806488ᴇ−23; // Chemistry
G:=6.67384ᴇ−11; // Physics
c:=299792458; // Physics
hbar:=1.054571726ᴇ−34; // Quantum

// Swartzchild radius (m)
LOCAL R:=(2*G*M)/c^2;

// Life (years)
LOCAL t:=M^3*5120*π*G^2/
(hbar*c^4*31556925.9747);

// Temperature (K)
LOCAL temp:=(hbar*c^3)/
(M*8*k*π*G);

// Surface Area (m^2)
LOCAL sa:=M^2*16*π*G^2/c^4;

// Gravity 
LOCAL gr:=c^4/(4*G*M);

// Results
PRINT();
PRINT("Schwartzchild Radius:");
PRINT(R+" m");
PRINT("Life:");
PRINT(t+" years");
PRINT("Temperature:");
PRINT(temp+" K");
PRINT("Surface Area:");
PRINT(sa+" m^2");
PRINT("Surface Gravity:");
PRINT(gr+" m/s^2");


// List
RETURN {R,t,temp,sa,gr};
END;

(edited 1/23/2018, see thread below)

Examples

Cygnus X-1: 14.8 solar masses

Schwartzchild Radius: 43705.6410566 m
Life: 6.79261706057 * 10^70 years
Temperature: 4.16932978074 * 10^-9 K (near absolute zero, very cold!)
Surface Area: 24004068275.4 m^2
Surface Gravity: 1.02819127807 * 10^12 m/s^2

Sagittarius A*, the center of our Milky Way Galaxy: 4.31 million solar masses

Schwartzchild Radius: 12727791415.8 m
Life: 1.67758214773 * 10^87 years
Temperature: 1.43169560917 * 10^-14 K
Surface Area: 2.03571024785 * 10^21 m^2
Surface Gravity: 3530680.02679 m/s^2

Source:

Jim Wisniewski. “Hawking Radition Calcualtor” Xaonon. January 3, 2017. http://xaonon.dyndns.org/hawking/ Retrieved December 26, 2017
Visit this user's website Find all posts by this user
Quote this message in a reply
01-05-2018, 09:05 AM
Post: #2
RE: HP Prime: Black Hole Characteristics – Hawking Radiation
Thanks!
Very useful program.

Salvo

∫aL√0mic (IT9CLU) :: HP Prime 50g 41CX 71b 42s 39s 35s 12C 15C - DM42, DM41X - WP34s Prime Soft. Lib
Visit this user's website Find all posts by this user
Quote this message in a reply
01-20-2018, 12:23 PM
Post: #3
RE: HP Prime: Black Hole Characteristics – Hawking Radiation
(01-05-2018 03:32 AM)Eddie W. Shore Wrote:  HP Prime: Black Hole Characteristics – Hawking Radiation

<...>
HP Prime Program BLACKHOLE

Code:
EXPORT BLACKHOLE()
BEGIN
// EWS 2018-01-04
// Hawking Radiation

// Input of mass
LOCAL ch,M;
INPUT({M,{ch,{"kg","Solar Mass"}}},
"Mass",{"Mass: ","Unit: "});

IF ch:=2 THEN
M:=1.988435ᴇ30*M;

<...>
<...>
http://xaonon.dyndns.org/hawking/ Retrieved December 26, 2017

Hello,

nice program - had to try it immediately with my brand new HP Prime Smile

Yet - it has a small error: If you try to change the input units to [kg], instead of [solar masses], the the check goes wrong:
Code:
IF ch:=2 THEN

should read

Code:
IF ch=2 THEN

With this small change it works nicely and delivers good results. The bug is in IF ch:=2, this sets ch to 2, instead of comparing it.
Find all posts by this user
Quote this message in a reply
01-23-2018, 03:01 PM
Post: #4
RE: HP Prime: Black Hole Characteristics – Hawking Radiation
I think the line should be

IF ch==2 THEN

since two equal signs are used for comparison. It seems to work either way with the one or two equal signs. The code on the original thread is now corrected.

Much appreciation!

Eddie
Visit this user's website Find all posts by this user
Quote this message in a reply
Post Reply 




User(s) browsing this thread: 1 Guest(s)