Most impressive/complex/amazing C-series program?

[Gerson W. Barbosa]

(04-14-2018 10:14 AM)Thomas Okken Wrote:  

(04-14-2018 09:29 AM)Gerson W. Barbosa Wrote:  Yes, that’s for Free42 only. VIEW Y on Free42 would exhibit only the first 12 significant digits. The FWIW program is mentioned in this thread, but it’s not available in the Free42 website anymore.

Hmm. Yes, I removed that program after I implemented full-precision Copy and SHOW, figuring those changes made it redundant. I didn't think about printing full precision, though. Gerson, if you could send me your copy, I'll put it back.

Here it is:


00 { 404-Byte Prgm }
01▸LBL "FWIW"
02 GTO 01
03▸LBL 00
04 "↓ bin≤16 dec≤34"
05 34
06 "↓ grouping size"
07 34
08 "↓ 1=SCI 3=ENG"
09 3
10 RTN
11▸LBL 01
12 REAL?
13 GTO 02
14 GTO 10
15▸LBL 02
16 X=0?
17 GTO 10
18 X<>Y
19 STO ".Y."
20 R↓
21 STO ".X."
22 R↓
23 STO ".Z."
24 R↓
25 STO ".T."
26 LASTX
27 STO ".L."
28 R↑
29 XEQ 00
30 STO ".M."
31 R↓
32 STO ".G."
33 R↓
34 1
35 -
36 STO ".J."
37 CLA
38 R↓
39 SIGN
40 LASTX
41 ABS
42 ENTER
43 LOG
44 ENTER
45 X≥0?
46 GTO 03
47 FP
48 X=0?
49 GTO 03
50 R↓
51 IP
52 1
53 -
54 ENTER
55▸LBL 03
56 R↓
57 IP
58 STO ".E."
59 RCL ".M."
60 MOD
61 STO- ".E."
62 STO- ".J."
63 R↓
64 RCL ".E."
65 10↑X
66 X=0?
67 GTO 08
68 ÷
69 ×
70 AIP
71 FS? 28
72 ├"."
73 FC? 28
74 ├","
75 LASTX
76 FP
77 RCL ".G."
78 X<>Y
79▸LBL 04
80 10
81 ×
82 AIP
83 FP
84 DSE ".J."
85 X=0?
86 GTO 06
87 DSE ST Y
88 GTO 04
89 ALENG
90 22
91 X≤Y?
92 GTO 05
93 X<>Y
94 RCL+ ".G."
95 X<Y?
96 GTO 05
97 R↓
98 LASTX
99 RCL+ ".J."
100 X≥Y?
101 ├"[LF]"
102▸LBL 05
103 ├" "
104 RCL ".G."
105 R↑
106 GTO 04
107▸LBL 06
108 ALENG
109 22
110 X≤Y?
111 GTO 07
112 10
113 POSA
114 X<0?
115 ├"[LF]"
116▸LBL 07
117 ├" ᴇ"
118 RCL ".E."
119 AIP
120 GTO 09
121▸LBL 08
122 "Went out of"
123 ├" range! :("
124▸LBL 09
125 AVIEW
126 CLA
127 RCL ".L."
128 STO ST L
129 RCL ".T."
130 RCL ".Z."
131 RCL ".Y."
132 RCL ".X."
133 CLV ".M."
134 CLV ".G."
135 CLV ".J."
136 CLV ".E."
137 CLV ".L."
138 CLV ".T."
139 CLV ".Z."
140 CLV ".Y."
141 CLV ".X."
142▸LBL 10
143 END