List Commands Library for 50g

[pier4r]

If I am not mistaken, the following is so far a program of mine that uses ListExt the most. It seems that ListExt is tailored for it.

The problem that it solves may become a list processing challenge if I can formalize it in a simpler way.

The program is just an initial draft, although working

Code:


sampleSizeTest
    \<<
      100 "dbSize" DROP
      {} "dbList" DROP
      { 45 25 20 10} "choicesDistr" DROP
        @actually this set the dbSize as well
      DUP SIZE "choicesNum" DROP
      10 "sampleSize" DROP
      {} "sampleList" DROP
      {} "sampleResult" DROP
    
      \->
      @input
      dbSize
      
      @local var
      dbList
      choicesDistr
      choicesNum
      sampleSize
      sampleList
      sampleResult
      
      \<<
        @set the db
        choicesDistr LSUM 'dbSize' STO
        
        @setting in homogeneous blocks
        1 choicesNum
        FOR choiceInd
          @create 'n' times the entry choiceInd
          choiceInd
          choicesDistr choiceInd GET
          LNDUP
          'dbList' SWAP STO+
        NEXT
        
        @here we have the db
        
        @going to sample the db
        
        @creating a list of random positions to pick
        dbSize LSEQ LSHUF
        sampleSize
        LFRST
        dbList
        SWAP LPICK
        
        @got the sample on the stack
        'sampleList' STO
        
        @counting
        1 choicesNum
        FOR choiceInd
          sampleList choiceInd LCNT
          'sampleResult' SWAP STO+
        NEXT
        
        "choices in source db"
        choicesDistr dbSize /
        "sample result"
        sampleResult sampleSize /
      \>>
    \>>