42S statistics registers

[Dave Britten]

I have a little program that makes this trivially easy. Just XEQ the appropriate label and it will give you the summation register in X, regardless of your current stat reg location. It also spits out an error if you try to recall one of the extended sums while in linear mode. It's written so as not to disturb the stack.

Code:

00 { 239-Byte Prgm }
01▸LBL "ΣX"
02 ΣREG?
03 GTO 00
04▸LBL "ΣX↑2"
05 ΣREG?
06 GTO 01
07▸LBL "ΣY"
08 ΣREG?
09 GTO 02
10▸LBL "ΣY↑2"
11 ΣREG?
12 GTO 03
13▸LBL "ΣXY"
14 ΣREG?
15 GTO 04
16▸LBL "ΣN"
17 ΣREG?
18 GTO 05
19▸LBL "ΣLNX"
20 FS? 61
21 GTO 99
22 ΣREG?
23 GTO 06
24▸LBL "ΣLN2X"
25 FS? 61
26 GTO 99
27 ΣREG?
28 GTO 07
29▸LBL "ΣLNY"
30 FS? 62
31 GTO 99
32 ΣREG?
33 GTO 08
34▸LBL "ΣLN2Y"
35 FS? 62
36 GTO 99
37 ΣREG?
38 GTO 09
39▸LBL "ΣLXLY"
40 FS? 63
41 GTO 99
42 ΣREG?
43 GTO 10
44▸LBL "ΣXLNY"
45 FS? 62
46 GTO 99
47 ΣREG?
48 GTO 11
49▸LBL "ΣYLNX"
50 FS? 61
51 GTO 99
52 ΣREG?
53 ISG ST X
54▸LBL 11
55 ISG ST X
56▸LBL 10
57 ISG ST X
58▸LBL 09
59 ISG ST X
60▸LBL 08
61 ISG ST X
62▸LBL 07
63 ISG ST X
64▸LBL 06
65 ISG ST X
66▸LBL 05
67 ISG ST X
68▸LBL 04
69 ISG ST X
70▸LBL 03
71 ISG ST X
72▸LBL 02
73 ISG ST X
74▸LBL 01
75 ISG ST X
76▸LBL 00
77 SF 30
78 RCL IND ST X
79 RTN
80▸LBL 99
81 "Invalid"
82 AVIEW
83 END

  StatRegs.zip (Size: 323 bytes / Downloads: 4)