Threaded Mode | Linear Mode

Thomas Klemm · 10-14-2018, 01:47 PM

Here's another approach for the HP-42S using numeric integration.
For the dome an ellipsoid is used.

Code:

00 { 60-Byte Prgm }

01▸LBL "AREA"

02 MVAR "t"

03 RCL "t"

04 RCL "h0"

05 X<Y?

06 GTO 00

07 ÷

08 2

09 ×

10 1

11 -

12 +/-

13 ACOS

14 LASTX

15 RCL ST Y

16 SIN

17 ×

18 -

19 RTN

20▸LBL 00

21 -

22 RCL "d"

23 X<Y?

24 GTO 00

25 PI

26 RTN

27▸LBL 00

28 -

29 RCL÷ "v0"

30 X↑2

31 1

32 X<>Y

33 -

34 PI

35 ×

36 END

Code:

00 { 44-Byte Prgm }

01▸LBL "TANK"

02 PGMINT "AREA"

03 STO "ULIM"

04 CLX

05 STO "LLIM"

06 INTEG "t"

07 RCL "r"

08 X↑2

09 ×

10 RCL÷ "in3/gal"

11 END

Make sure to initialise these variables and set the calculator to RAD mode:

Code:

h0=            12.0000

d=            180.0000

v0=            36.0000

r=             72.0000

in3/gal=      231.0000

Set the accuracy ACC to something reasonable like \(10^{-8}\).

Examples

3 XEQ "TANK"
16.9551

8 XEQ "TANK"
175.0894

112 XEQ "TANK"
7,473.2363

195 XEQ "TANK"
13,324.4312

198 XEQ "TANK"
13,532.5136

Compare this to the examples given in table 25-3 of the paper:

\(
\begin{matrix}
\textbf{Measurement #} & \textbf{H (total vertical level)} & \textbf{# Gallons} \\
1 & 3" & 21 \\
2 & 8" & 200 \\
3 & 112" & 7,473 \\
4 & 195" & 13,284 \\
5 & 198" & 13,444
\end{matrix}
\)

Kind regards
Thomas