The Museum of HP Calculators

# Distance between Lines in Space for the HP-41C/CV/CX

This program is Copyright © HP and is used here by permission. It was originally printed in the Geometry Solution Book. This program was entered and uploaded by Tony Duell.

This program is supplied without representation or warranty of any kind. Tony Duell, Hewlett Packard and The Museum of HP Calculators therefore assume no responsibility and shall have no liability, consequential or otherwise, of any kind arising from the use of this program material or any part thereof.

Documentation Information (CD or source code)
How to get this Program to your Calculator (via HP-IL, disk, wand, and fingers)

## Program Listing

```LINE  KEYS
01 LBL "DIST"
02 "DIST. B. LINES"
03 AVIEW
04 2.2
05 STO 00
06 1.002
07 STO 01
08 CF 29
09 FIX 00
10 LBL 02
11 "X"
12 XEQ 12
13 "Y"
14 XEQ 12
15 "Z"
16 XEQ 12
17 "X"
18 XEQ 13
19 "Y"
20 XEQ 13
21 "Z"
22 XEQ 13
23 ISG 01
24 GTO 02
25 RCL 08
26 ST- 11
27 RCL 09
28 ST- 12
29 RCL 10
30 ST- 13
31 RCL 02
32 ST- 05
33 ST- 08
34 RCL 03
35 ST- 06
36 ST- 09
37 RCL 04
38 ST- 07
39 ST- 10
40 RCL 11
41 RCL 06
42 RCL 05
43 RCL 12
44 XEQ 14
45 RCL 12
46 RCL 07
47 RCL 06
48 RCL 13
49 XEQ 14
50 RCL 13
51 RCL 05
52 RCL 07
53 RCL 11
54 XEQ 14
55 RCL 05
56 X^2
57 RCL 03
58 X^2
59 +
60 RCL 04
61 X^2
62 +
63 SQRT
64 1/X
65 RCL 08
66 RCL 04
67 *
68 RCL 09
69 RCL 05
70 *
71 +
72 RCL 10
73 RCL 03
74 *
75 +
76 *
77 FIX 04
78 "D="
79 ARCL X
80 AVIEW
81 STOP
82 LBL 13
83 ARCL 01
84 "-PRIME ?"
85 GTO 15
86 LBL 12
87 ARCL 01
88 " ?"
89 LBL 15
90 PROMPT
91 STO IND 00
92 ISG 00
93 RTN
94 LBL 14
95 *
96 STO IND 01
97 RDN
98 *
99 ST- IND 01
100 ISG 01
101 RTN
102 END
```