Post Reply 
(HP-65) Welding Programs (x3)
07-16-2021, 06:57 PM (This post was last modified: 07-16-2021 06:57 PM by SlideRule.)
Post: #1
(HP-65) Welding Programs (x3)
An extract (pgs 58-59) from the 1975-05 edition of Welding design and fabrication magazine, complete with program instructions/listings, examples, equations, illustrations, etc.

       

BEST!
SlideRule
Find all posts by this user
Quote this message in a reply
07-17-2021, 09:48 AM (This post was last modified: 07-17-2021 11:22 AM by C.Ret.)
Post: #2
RE: (HP-65) Welding Programs (x3)
Hello,
And thanks for sharing this !

Once again an interesting catch of a practical application from the handle-calculator's holy times.

Indeed, also the first time I read RPN code in an array format!

I get in trouble finding out how to make this code computing as expected, here is a transcription of the matrix code which may be easier to decipher than the extract from the page capture. I voluntary replace the difficult to read traditional divide sign ÷ by a slash to spare reader’s time (since this was the main source of my own pains here after an hidden ENTER^ key deguise into what appears to be a sort of f or 1 or ! or ↑ little symbol - at the sixteen position of the matrix code).

Code:
LBL        A          f`¹        SF 1       GTO        1          LBL        B          f          SF 1      
LBL        1          RCL(1)     RCL(2)     -          ENTER↑     STO(5)     RCL(4)     f          TAN       
×          STO(6)     2          /          ×          STO(7)     RCL(1)     RCL(3)     ×          STO       
+          7          RCL(6)     RCL(3)     +          STO(5)     f`¹        TF 2       2          ×         
f          TF 1       GTO        2          1          +          .          6          g          y^x       
1          6          /          STO(6)     RCL(5)     ×          2          ×          3          /         
RCL(7)     +          STO(7)     3          .          4          ×          RTN        LBL        2         
2          5          +          .          6          g          y^x        4          .          4         
/          STO(6)     RCL(5)     ×          2          ×          3          /          RCL(7)     +         
STO(7)     .          0          0          7          8          5          ×          RTN

The partially merged code from HP-65 is for me a bit hard to read. Here is a transcription of the code in a more conventianal or later time columnwise RPN transcription. In the right columns, an attempt to translate into an HP-42S/DM-42S newest RPN flavor code.

Code:
LBL                                                                              
A                 001 LBL A                                                      
f`¹                                                                              
SF 1              002 CF 1              %% Emperial units mode set               
GTO                                                                              
1                 003 GTO 1                                                      
LBL                                                                              
B                 004 LBL B                                                      
f                                                                                
SF 1              005 SF 1              %% Metric units mode set                 
LBL                                                                              
1                 006 LBL 1             %% MAIN START                            
RCL(1)            007 RCL 1                                                      
RCL(2)                                                                           
-                 008 RCL-2                                                      
↑                 009 ENTER             %% hidden ENTER^ key here !              
STO(5)            010 STO 5                                                      
RLC(4)            011 RCL 4                                                      
f                                                                                
TAN               012 TAN                                                        
×                 013 *                                                          
STO(6)            014 STO 6             %% R6: ← b                               
2                 015 2                                                          
÷                 016 /                                                          
×                 017 *                                                          
STO(7)            018 STO 7             %% R7: ← A1                              
RCL(1)            019 RCL 1                                                      
RCL(3)                                                                           
×                 020 RCL*3                                                      
STO                                                                              
+                                                                                
7                 021 STO+7             %% R7: ← A1+A2                           
RCL(6)            022 RCL 6                                                      
RCL(3)                                                                           
+                 025 RCL+3                                                      
STO(5)            026 STO 5             %% R5: ← W                               
f`¹                                                                              
TF 2                                    %% T Joint cases test                    
| 2               027 FC? 2                                                      
| ×               028 RCL+5             %% x: ← 2W                               
f                                                                                
TF 1              029 FS? 1                                                      
| GTO             030 GTO 2                                                      
| 2                                     %% Emperial Calculations Unit            
1                 031 1                                                          
+                 032 +                                                          
.                                                                                
6                 033 0,6                                                        
g                                                                                
y^x               034 Y^X                                                        
1                                                                                
6                 035 16                                                         
÷                 036 /                                                          
STO(6)            037 STO 6             %% R6: ← a (in)                          
RCL(5)                                                                           
×                 038 RLC*5                                                      
2                 039 2                                                          
*                 040 *                                                          
3                 041 3                                                          
÷                 042 /                 %% A3 (in²)                              
RCL(7)                                                                           
+                 043 RCL+7                                                      
STO(7)            044 STO 7             %% R7: ← AT=A1+A2+A3 (in²)               
3                                                                                
.                                                                                
4                 045 3.4                                                        
×                 046 *                                                          
RTN               047 RTN               %% DISPLAY Weight (lb/ft)                
LBL                                                                              
2                 048 LBL 2             %% Metric Calculations Unit              
2                                                                                
5                 049 25                                                         
+                 050 +                                                          
.                                                                                
6                 051 .6                                                         
g                                                                                
y^x               052 y^x                                                        
4                                                                                
.                                                                                
4                 053 4.4                                                        
÷                 054 /                                                          
STO(6)            055 STO 6             %% R6: ← a (mm)                          
RCL(5)                                                                           
×                 056 RCL*5                                                      
2                 057 2                                                          
×                 058 *                                                          
3                 059 3                                                          
÷                 060 /                 %% A3 (mm²)                              
RCL(7)                                                                           
+                 061 RCL+7                                                      
STO(7)            062 STO 7             %% R7: AT←A1+A2+A3 (mm²)                 
.                                                                                
0                                                                                
0                                                                                
7                                                                                
8                                                                                
5                 063 7.85E-03                                                     
×                 064 *                                                          
RTN               065 END               %% DISPLAY Weight (Kg/m)

This makes this transcription a curious beast mixing oldest with newest RPN !
Find all posts by this user
Quote this message in a reply
07-17-2021, 09:31 PM (This post was last modified: 07-18-2021 07:03 AM by C.Ret.)
Post: #3
RE: (HP-65) Welding Programs (x3)
By observing the tree program codes, I notice a lot of similarities and repetitions.
In fact, regrouping all the tree programs in one code is possible on the amazing HP-65 without changing much of the instructions:

Instructions:

Program the HP-65 using the following sequence of steps:
  1. Turn on the calculator (or your simulator/emulator software),
  2. Switch the calculator to "Write/Program" and clear it from previous program,
  3. Enter the following code into the calculator,
  4. When completed switch calculator back to "Run",
  5. Work the numerous examples to verify correctness of the entered code,
  6. When verified, eventually record the program on a new magnetic card :
    • To record the program, switch to "W/Program" and pass a magnetic card into the calculator,
    • Switch back to "RUN" mode and clip the corner of the card to write protect it,
    • Put the necessary identification and labels on the card
  7. Load a previous saved program form card with switch in "RUN" position and insert the labeled card on top of the keyboard.



Programming sequence:
Code:
    00 00
01.    23    LBL
02.    11    A
03.    15    E
04.    03    3
05.    83    .
06.    04    4
07.    33 08 STO 8
08.    01    1
09.    06    6
10.    41    ENTER↑
11.    01    1
12.    22    GTO
13.    01    1

14.    23    LBL
15.    12    B
16.    15    E
17.    07    7
18.    83    .
19.    08    8
20.    05    5
21.    43    EEX
22.    03    3
23.    42    CHS
24.    33 08 STO 8
25.    04    4
26.    83    .
27.    04    4
28.    41    ENTER^
29.    02    2
30.    05    5
31.    22    GTO
32.    01    1

33.    23    LBL
34.    15    E
35.    33 06 STO 6
36.    34 01 RCL 1
37.    34 01 RCL 2
38.    51    -
39.    34 06 RCL 6
40.    34 04 RCL 4
41.    34 06 RCL 6
42.    81    /
43.    31    f
44.    06    TAN
45.    31    f
46.    81    TF 2
47.    02      2
48.    81      /
49.    71    x
50.    71    x
51.    41    ENTER↑
52.    35 08 g ROLDN
53.    71    x
54.    02    2
55.    81    /
56.    33 07 STO 7
57.    35 09 g ROLUP
58.    34 03 RCL 3
59.    61    +
60.    33 05 STO 5
61.    24    RTN

62.    23    LBL
63.    01    1
64.    34 05 RCL 5
65.    31    f
66.    61    TF 1
67.    02      2
68.    71      x
69.    61    +
70.    83    .
71.    06    6
72.    35    g
73.    05    y^x
74.    35 07 g X<>Y
75.    81    /
76.    33 06 STO 6
77.    02    2
78.    31    f
79.    81    TF 2
80.    41      ENTER↑
81.    71      x
82.    34 05 RCL 5
83.    71    x
84.    71    x
85.    03    3
86.    81    /
87.    34 01 RCL 1
88.    34 03 RCL 3
89.    71    x
90.    34 07 RCL 7
91.    61    +
92.    61    +
93.    33 07 STO 7
94.    34 08 RCL 8
95.    71    x
96.    24    RTN

Problem-solving sequence:
  1. Enter length data: \( t \) in STO(1), \(f \) in STO(2), \( r \) in STO(3) and \( \theta \) in STO(2).
    Enter all length in expected unit (in) for imperial unit system or in (mm) for metric unit system. Don't mix.
    Select corresponding trigonometric angle mode (DEG/RAD/GRAD).
  2. Use Flag 1 to indicate type of joint :
    Clear flag 1 for Butt joint or V grove joint data by pressing f-1 CF 1.
    Set flag 1 for T-shape joint data only by pressing f SF 1.
  3. Use Flag 2 to indicate double bevel groove joint :
    Clear flag 2 for single bevel groove joint or single V grove joint (cf. original programs 1 & 3) by pressing f-1 CF 2 .
    Set flag 2 for DOUBLE bevel groove joint (cf. original program 2)by pressing f SF 2.
  4. Enter 1 for single or double bevel Butt Joint AND T-shape Joint
    Enter 2 for single V-shape Grove joint
  5. Start computation by pressing A (for data in imperial units) or B (for data in metric units).
    Mass of weld metal will be display in respectively (lb/ft) or (Kg/m) units.
  6. Other data can be retrieve from register :
    Press RCL(7) for total area \( A_t \) in (in²) or (mm²),
    Press RCL(6) for \( a \) in (in) or (mm),
    Press RCL(5) for wifth \(W \) in (in) or (mm)
  7. For corner joint use either Butt or T joint or average them.


Commented and structured program listing:
Code:
LBL A
  E  3.4             STO 8   16  ENTER↑  1  GTO 1                        ;; Initiate imperial unit computation

LBL B
  E  7.85 EEX 3 CHS  STO 8  4.4  ENTER↑ 25  GTO 1                        ;; Initiate metric unit computation

LBL E                                                                   ;;; Sub program ;;;;
  STO 6  RCL 1  RCL 2  -  RCL 6  RCL 4  RCL 6  /  f TAN  f TF 2  2  /    ;; Compute b : argument 1=single or double bevel groove   2=V grove joint
  x  x  ENTER↑  g ROLDN  x  2  /  STO 7                                  ;; Initiate area summation in register R7: 
  g ROLUP  RCL 3  +  STO 5                                               ;; R5: ← W
RTN

LBL 1                                                                   ;;; End program ;;;;
  RCL 5  f TF 1  2  x                                                    ;; Arrange parameter for T joins  (Flag 1 set)
  +  .6  g y^x  g X<>Y  /  STO 6                                         ;; R6: ← a
  2  f TF 2  ENTER↑  x                                                   ;; Arrange parameter for DOUBLE bevel case (Flag 2 set) 
  RCL 5  x  x  3  /  RCL 1  RCL 3  x  RCL 7  +  +  STO 7                 ;; R7: ← total area At per unit length of welding
  RCL 8  x                                                               ;; X ← Weight of metal per unit length of welding (lb/ft) or (Kg/m)
RTN
Find all posts by this user
Quote this message in a reply
07-18-2021, 04:30 PM
Post: #4
RE: (HP-65) Welding Programs (x3)
How interesting the fusion of the three programs, and the new instructions for their execution are very clear. I wonder if you would be willing to translate the codes for use on the HP67 / 97? Pedro
Find all posts by this user
Quote this message in a reply
Post Reply 




User(s) browsing this thread: 1 Guest(s)