Post Reply 
(42S) Smith Chart Conversions
11-23-2019, 02:37 PM
Post: #1
(42S) Smith Chart Conversions
Introduction

The program SMITH brings generates a custom menu that allows the user to convert between four factors:

RL: return loss
p: reflection coefficient
s: voltage standing ratio
SWR: standing wave ratio

p = 10^-(RL/20)
s = (1 + p)(1 - p)
SWR = 20 * log s

Programs here:

HP 42S/DM42 Program: SMITH

Code:
00 { 111-Byte Prgm }
01▸LBL "SMITH"
02 "RL>p"
03 KEY 1 GTO 01
04 "p>s"
05 KEY 2 GTO 02
06 "s>SWR"
07 KEY 3 GTO 03
08 "SWR>s"
09 KEY 4 GTO 04
10 "s>p"
11 KEY 5 GTO 05
12 "p>RL"
13 KEY 6 GTO 06
14 MENU
15▸LBL 07
16 STOP
17 GTO 07
18▸LBL 01
19 +/-
20▸LBL 04
21 20
22 ÷
23 10↑X
24 RTN
25▸LBL 02
26 STO 00
27 1
28 +
29 1
30 RCL- 00
31 ÷
32 RTN
33▸LBL 05
34 STO 00
35 1
36 -
37 1
38 RCL+ 00
39 ÷
40 RTN
41▸LBL 06
42 1/X
43▸LBL 03
44 LOG
45 20
46 ×
47 RTN
48 .END.

Example 1

Convert SWR of 12 to RL:

[XEQ] (SMITH)
12 (SWR>s) (s>p) (p>RL)

Result: 4.45901

Conversions Between Complex Reflection Coefficient and Impedance

It is recommended that you set the calculator to Degree and Polar modes. To enter complex numbers in polar mode,

Z→R: Convert from impedance to complex reflection coefficient
Stack: Z, Z0 (characteristic impedance)

Γ = (Z/Z0 - 1) / (Z/Z0 + 1)

R→Z: Convert from complex reflection coefficient to impedance
Stack: Z0, Γ

Z = Z0 * (1 + Γ) / (1 - Γ)

HP 42S/DM42 Programs: Z→R and R→Z

Code:
00 { 19-Byte Prgm }
01▸LBL "Z→R"
02 ÷
03 ENTER
04 ENTER
05 1
06 -
07 X<>Y
08 1
09 +
10 ÷
11 RTN
12 .END.

00 { 20-Byte Prgm }
01▸LBL "R→Z"
02 ENTER
03 ENTER
04 1
05 +
06 X<>Y
07 1
08 -
09 +/-
10 ÷
11 ×
12 RTN
13 .END.

Example 2

In a system with the resistance of 66 Ω has the impedance of 10 ∠ 15°. What is the reflection coefficient?

(Degree and Polar Mode)
10 [ENTER] 15 [(shift)] (COMPLEX) 66
[XEQ] ( Z→R )

Result: 0.40469 ∠ -163.92848

Example 3

What is the impedance of a system with a reflection coefficient of 0.86∠50° with a resistor of 125 Ω?

(Degree and Polar Mode)
125 [ENTER] 0.86 [ENTER] 50 [(shift)] (COMPLEX)
[XEQ] ( R→Z )

Result: 246.80096 ∠ 78.82055°

Source:

Step-by-Step Solutions For Your HP Calculator: Engineering Applications (HP-32S). Hewlett Packard. Edition 1. Corvallis, OR June 1988

Blog Link: http://edspi31415.blogspot.com/2019/11/h...sions.html
Visit this user's website Find all posts by this user
Quote this message in a reply
Post Reply 




User(s) browsing this thread: 1 Guest(s)