Post Reply 
(12C) Hyperfocal Distance
04-30-2018, 09:22 AM (This post was last modified: 04-30-2018 09:36 AM by Gamo.)
Post: #1
(12C) Hyperfocal Distance
Hyperfocal Distance is the closest distance at which a lens can be focused while keeping objects at infinity acceptably sharp.
When using hyperfocal distance, you are focusing the lens to a particular distance determined by the focal length and Aperture combination that you are using to ensure that everything from half the hyperfocal distance to infinity is acceptable sharp.


Formula: H = (f^2 / Ac) + f

H - Hyperfocal distance in millimetres
f - Lens focal length in millimetres
A - Aperture the f-number
c - Circle of confusion in millimetres

The Circle of Confusion size that you need to use in the above formula are as follows, these camera formats are used mostly by digital SLR

- Full Frame Camera (36x24mm) = 0.03mm
- Sensor with 1.3 times crop factor of Full Frame = 0.023mm
- Sensor with 1.6 times crop factor of Full Frame = 0.019mm

How to input information:
1. Store sensor size factor to Register 2 (STO 2)
2. Input Lens focal length
3. Input Aperture (f-number)

Program:
Code:

01 STO 1
02 X<>Y
03 STO 0
04 RCL 0
05 ENTER
06  x
07 RCL 1
08 RCL 2
09  x
10  /
11 RCL 0
12  +
13 EEX
14  3
15  1/X
16  x
17 GTO 00


Example:
You decide to shoot the scene with a 35mm lens with the Full Frame camera. Lets set the Aperture at f/11 What is the Hyperfocal Distance in meter?

0,03 STO 2 > 0,03 // Full Frame camera sensor size
35 ENTER 11 > 3.75 // 35mm Lens with f/11 Aperture

Remark: This program convert millimeter to Meter as a distance unit.

If you focused your lens at 3.75 meter and used an Aperture of f/11 with 35mm lens everything from half of the hyperfocal distance (1.87m) till infinity will be rendered acceptable sharp in the photograph.

Gamo
Find all posts by this user
Quote this message in a reply
04-30-2018, 10:02 AM (This post was last modified: 04-30-2018 10:19 AM by Dieter.)
Post: #2
RE: (12C) Hyperfocal Distance
(04-30-2018 09:22 AM)Gamo Wrote:  Hyperfocal Distance is the closest distance at which a lens can be focused while keeping objects at infinity acceptably sharp.

Ah, great – finally something photography related. ;-)

(04-30-2018 09:22 AM)Gamo Wrote:  Formula: H = (f^2 / Ac) + f

A simple formula – no need to waste three registers for this.
Hey, it's RPN – you can do such things directly on the stack:

Code:
01  RCL 0
02  0
03  +
04  x
05  X<>Y
06  ENTER
07  x
08  X<>Y
09  /
10  +
11  EEX
12  3
13  /
14  GTO 00

Note: the CoC is assumed to be stored in R0 here.

The trick here is the "0 +" which pushes the focal length to T and pops it back to Z. This way it fills the higher stack registers and can be conveniently added in step 10.

But it's still 14 steps. So here is the definite nerd version:

Code:
01  RCL 0
02  0
03  +
04  x
05  /
06  x
07  +
08  EEX
09  3
10  /
11  GTO 00

That's better. ;-)

Hint: After step 04 has been executed A·c is in X and the rest of the stack is filled with f. So the next steps calculate f/Ac, then f·f/Ac, and finally f·f/Ac + f.

You don't even have to prestore the CoC in R0 (or R2). If you want to, you can also pass it on the stack: Simply replace the initial "RCL 0" with an ENTER (just to be sure to terminate number entry, you can also simply remove the first line).

This way you can type  f [ENTER] A [ENTER] c [R/S]

35 [ENTER] 11 [ENTER] 0,03 [R/S] => 3,75

Dieter
Find all posts by this user
Quote this message in a reply
04-30-2018, 12:19 PM (This post was last modified: 04-30-2018 12:20 PM by Gamo.)
Post: #3
RE: (12C) Hyperfocal Distance
Thanks Dieter
The nerd version is so cool very nice one.

Gamo Smile
Find all posts by this user
Quote this message in a reply
04-30-2018, 01:18 PM (This post was last modified: 04-30-2018 01:22 PM by Dieter.)
Post: #4
RE: (12C) Hyperfocal Distance
(04-30-2018 12:19 PM)Gamo Wrote:  The nerd version is so cool very nice one.

Here's another idea: instead of the CoC simply enter the crop factor. Which is what most users will be more familiar with:

Code:
01  1/x
02  ,
03  0
04  3
05  x
06  x
07  /
08  x
09  +
10  EEX
11  3
12  /
13  GTO 00

"full frame":
35 [ENTER] 11 [ENTER] 1 [R/S] => 3,75

APS-C:
35 [ENTER] 11 [ENTER] 1,6 [R/S] => 5,97

(Micro-) Four Thirds:
35 [ENTER] 11 [ENTER] 2 [R/S] => 7,46

@Mike: yes, of course the final "+ f" usually can be omitted. At least unless you know your lens' exact focal length (not just the nominal one) and the effective geometric aperture (not just what you see in the display or on the lens, and f/11 actually is supposed to be f/11,314) and finally if the whole concept of this formula applies at all. Personally, I have always simply calculated f²/Ac. Which still leaves the question of the reference point: 3,75 meters from where? From the image plane? From the lens' principal plane? And if so, from which one... etc. etc. etc.

Dieter
Find all posts by this user
Quote this message in a reply
04-30-2018, 01:42 PM
Post: #5
RE: (12C) Hyperfocal Distance
Mike and Dieter gave more detail information on this subject that is very interesting.

This formula give a good estimate of the distance from the camera .

The good thing is today we all use digital camera so just shoot it and observe the different very easily.

Gamo
Find all posts by this user
Quote this message in a reply
04-30-2018, 04:40 PM (This post was last modified: 04-30-2018 04:43 PM by Dieter.)
Post: #6
RE: (12C) Hyperfocal Distance
(04-30-2018 02:56 PM)Mike (Stgt) Wrote:  Your questions reminds me Einsteins's saying "Never stop asking". I assume you do not expect me to give irrevocable answers to everything.

My questions were not addressed to you. I said that the "+ f" may be omitted and then I asked some questions to show that the simplifciation is perfectly fine if you consider the much larger tolerances in the input data and others.

(04-30-2018 02:56 PM)Mike (Stgt) Wrote:  For the average hobbyist this site could be sufficient -- until you find evident discrepancies. (BTW, it is not my site, I found it by chance).

Sure, I visited Elmar's website already years ago. We even had the one or other discussion on mathematical and photography-related details.

(04-30-2018 02:56 PM)Mike (Stgt) Wrote:  I have only one question, if you say
Quote:Personally, I have always simply calculated f²/Ac.
could you please estimate the relative error for the different possible (and impossible) reference points you all pinpointed and compare them with the error of your simplification?

The error, or better: the difference between the two equations is one focal length. In relative terms this is Ac/f which usually is < 1/f. As already noted in my previous post, this is negligible compared to the other factors: the true focal length alone can differ by several percent from the nominal value. Different reference planes (image plane? principal plane?) alone account for a difference larger than 1·f. But, Mike, why are you asking this? We both know that there is no relevant difference between the two equations. Don't we?

Dieter
Find all posts by this user
Quote this message in a reply
04-30-2018, 08:57 PM (This post was last modified: 05-01-2018 05:10 PM by Dieter.)
Post: #7
RE: (12C) Hyperfocal Distance
(04-30-2018 07:42 PM)Mike (Stgt) Wrote:  I only wanted to know how you justify to "ignore" a difference of up to 5% and more on the one hand and otherwise mind about the exact location of the reference point. In addition with the repeated "etc. etc. etc." you signify there are even more possibilities or questions and you know about it.

There is a simple answer: just because I know of the inherent inaccuracy of the input data and the result I do not care about a difference of one focal length and consider the simplified formula more than good enough.

In detail: Why care about 5 cm difference in the hyperfocal distance when 1% tolerance in the focal length causes twice that difference? And how would one distinguish 10 m and 10,05 m on the distance scale even of a classic 1970s manual focus rangefinder lens? Let alone today's virtually useless scales on AF-lenses where the 1-m-mark is right beside the infinity symbol. #-}

Re. "where to align the tape measure": the formula (with the added f) calculates the distance measured from the lens' front principal plane. So let's hope you got the manufacturer's data sheet for the lens in question. On the other hand the distances scales on lenses refer to the image plane. Which is roughly (!) one more focal length away. But then... who cares – see above.

Addendum:

If I got the math right, the hyperfocal distance from the image plane is f²/Ac + 2f + Ac. Here the term Ac can be neglected as it is within ≈ 1 mm for film / sensor formats up to "full frame". Even in large format photography it's merely 2 cm (f/90 · 0,2 mm) which is the same order as the principal plane distance which still would have to be added or subtracted, depending on the lens construction. Anyway, here is a 12C version that implements the complete formula:

Edit: new version with the formula rearranged as (f + Ac)² / Ac

Code:
01  1/x
02  ,
03  0
04  3
05  x
06  x
07  +
08  ENTER
09  ENTER
10  LstX
11  /
12  x
13  EEX
14  3
15  /
16  GTO 00

This yields the hyperfocal distance measured from the image plane. Which is usually marked on the camera body, so you get an unambiguous reference point. ;-)

As before, the input is  f [ENTER] A [ENTER] crop factor.
35 [ENTER] 11 [ENTER] 1 [R/S] => 3,78

If you want a slightly shorter version simply take the previous one and add another "+" before the "EEX 3". This ignores the Ac term.

Dieter
Find all posts by this user
Quote this message in a reply
05-01-2018, 08:23 PM
Post: #8
RE: (12C) Hyperfocal Distance
I'd like to thank the duo Gamo /Dieter.

Gamo for the input, as it is necessary for any discussion (no input, no discussion). Dieter for the optimization of many inputs that appears in the general software library and not only.

In my mind Dieter is the "optimizer" while Gamo is the "here, a new input!". Of course there are many others that produce nice contributions, but I noted the duo Gamo/Dieter quite often.

Wikis are great, Contribute :)
Find all posts by this user
Quote this message in a reply
05-02-2018, 06:31 AM (This post was last modified: 05-02-2018 08:02 PM by Dieter.)
Post: #9
RE: (12C) Hyperfocal Distance
(05-02-2018 12:55 AM)Mike (Stgt) Wrote:  
(04-30-2018 08:57 PM)Dieter Wrote:  [...] If I got the math right, the hyperfocal distance ... [...]

Which one? This wiki distinguishes two definitions of hyperfocal distance.

I refer to definition 1. Wikipedia gives the formula for the hyperfocal distance as object distance, i.e. measured from the lens' front principal plane. My formula gives the hyperfocal distance measured from the image plane, i.e. the sum of object distance and image distance, as it is common on photography. The distance scales on lenses refer to this plane. In the Wikipedia illustration this is H+x in the upper (1.) diagram. Here H is the object distance and x is the image distance.

But it is interesting to see that both established formulas have their corresponding defintions, so that one is not a simplification of the other. Instead they describe slightly different scenarios. In photography usually both definitions are considered equivalent. I have not realized this before.

(05-02-2018 12:55 AM)Mike (Stgt) Wrote:  For either formula corresponding to the definitions of hyperfocal distance I can not (or not yet) see a reason for the 3rd term (Ac) in your formula. Or is the wiki incomplete, or not so precise as I assume?

It is incomplete in that it does not give a formula for the sum of image distance and object distance, i.e. H+x.

You can derive the formula yourself: with g being the object distance and b being the image distance, b = gf/(g–f). This follows from the basic relation 1/b+1/g = 1/f. My formula calculates g+b. So simply substitute g with f²/Ac+f and there you are.

You can also get this from the Wikipedia formulas (here using A instead of N for the f-number):

Object distance:  H = f² / Ac + f
Image distance:  x = f + cf/D  =  f + cA
Distance from image plane:  H + x = f²/Ac + f + f + Ac

q.e.d.

Dieter
Find all posts by this user
Quote this message in a reply
05-02-2018, 08:02 PM
Post: #10
RE: (12C) Hyperfocal Distance
(05-02-2018 10:27 AM)Mike (Stgt) Wrote:  
(05-02-2018 06:31 AM)Dieter Wrote:  You can derive the formula yourself: with g being the object distance and b being the image distance, b = g²/(g–f). This follows from the basic relation 1/b+1/g = 1/f. My formula calculates g+b. So simply substitute g with f²/Ac+f and there you are.

Got it. Thank you.

Fine. You obviously could do it without the given b formula, because ...it was wrong.
Of course it should have read...

b = gf/(g–f)
- or -
b+g = g²/(g–f)

I corrected the previous post accordingly.

Dieter
Find all posts by this user
Quote this message in a reply
Post Reply 




User(s) browsing this thread: 1 Guest(s)