RPL/2

[JKB]

(02-03-2019 07:24 PM)pier4r Wrote:  Awesome that you still are dedicated on it despite the seemingly small interest. It is not easy! Well done.

I should finally use my raspi one day. I dislike unused powerful devices, damn me.

I use RPL/2 every days to run very large simulations (there are multithreading/multitasking capabilities in RPL/2).

Example:

Code:


#!/usr/local/bin/rpl -cspd

SPECIFICATION
<<
    "none" implicit
    nbrcpus 1 ->list crtab 'PROCESSUS' save

    <<
        // Les interruptions sont non interruptibles
        -> PROC
        <<
            "Interruption "
            PROC wfdata PROC recv drop ->str " depuis " + +
            PROC wfdata PROC recv drop
            dup ->str 3 roll swap + disp
            'PROCESSUS' swap 1 ->list { } put
            PROCESSUS disp
        >>
    >> 1 stoswi

    0
    -> J
    <<
        do
            // Recherche d'un processus disponible
            'PROCESSUS' 0

            while
                1 PROCESSUS size for I
                    if
                        PROCESSUS I 1 ->list get
                        { } same
                    then
                        drop I exit
                    end
                next

                dup 0 same
            repeat
                .1 wait
            end

            1 ->list
            J

            <<
                wfpoke peek drop2

                -> I J
                <<
                    rand wait
                    "Début thread "
                    I list-> drop ->str + disp
                    1 swi
                    J send
                    I list-> drop send wfack
                    "Fin thread "
                    I list-> drop ->str + disp
                >>
            >>

            1 swiqueue
            spawn swap drop dup 4 rolld put
            1 swiunlock
            "START" swap poke

            'J' incr
        until
            false
        end
    >>
>>

This program starts subprocess (SPAWN) , one by CPU thread. Each subprocess sends data to main thread. I use this kind of program to spawn ngspice simulations in parallel to compute amplifiers harmonic distorsion.

Since I have announce last release (this afternoon CET), sources were donwloaded three times and amd64 deb package once.