(41) Bulk Cylindrical Tank

[Thomas Klemm]

(10-14-2018 10:15 PM)Dieter Wrote:  The paper uses a "different" formula for the slant bottom section and assumes a spherical dome top with a given radius (which is different from the calculated radius).

This is something in the paper that I don't understand: Why would they determine the radius R graphically or by measurement when it can be calculated?

(10-15-2018 12:33 PM)Dieter Wrote:  2. If the dome top section is actually spherical there is exactly one solution: the radius R must be 90".

From your excellent sketch I concluded:

\(
\begin{align*}
a^2+r^2=R^2=(a+v_0)^2&=a^2+2av_0+v_0^2 \\
r^2&=2av_0+v_0^2
\end{align*}
\)

And thus:

\(2a=\frac{r^2-v_0^2}{v_0}\)

Let \(x\) be the radius of the surface in the dome on level \(v\).
Then:

\(
\begin{align*}
x^2 &= R^2-(a+v)^2 \\
&= R^2-a^2-2av-v^2 \\
&= r^2-(2a+v)v
\end{align*}
\)

And thus:

\(\left ( \frac{x}{r} \right )^2=1-\left ( \frac{2a}{r} + \frac{v}{r} \right )\frac{v}{r}\)

But since:

\(\frac{2a}{r}=\frac{r^2-v_0^2}{rv_0}=\frac{r}{v_0}-\frac{v_0}{r}\)

We end up with:

\(\left ( \frac{x}{r} \right )^2=1-\left ( \frac{r}{v_0}-\frac{v_0}{r} + \frac{v}{r} \right )\frac{v}{r}\)

Here's the modified program for the HP-42S:

Code:

00 { 72-Byte Prgm }
01▸LBL "AREA"
02 MVAR "t"
03 RCL "t"
04 RCL "h0"
05 X<Y?
06 GTO 00
07 ÷
08 2
09 ×
10 1
11 -
12 +/-
13 ACOS
14 LASTX
15 RCL ST Y
16 SIN
17 ×
18 -
19 RTN
20▸LBL 00
21 -
22 RCL "d"
23 X<Y?
24 GTO 01
25 PI
26 RTN
27▸LBL 01
28 -
29 RCL÷ "r"
30 RCL "r"
31 RCL÷ "v0"
32 ENTER
33 1/X
34 -
35 RCL+ ST Y
36 ×
37 1
38 X<>Y
39 -
40 PI
41 ×
42 END

Of course the constant \(\frac{r}{v_0}-\frac{v_0}{r}\) could be stored in another variable instead of calculating it again and again:

Code:

30 RCL "r"
31 RCL÷ "v0"
32 ENTER
33 1/X
34 -

Examples:

195 XEQ "TANK"
13,318.1905

198 XEQ "TANK"
13,509.0116

228 XEQ "TANK"
14,488.2093


Here I used \(10^{-12}\) for ACC. Do these results agree with your calculations?

Kind regards
Thomas