Mac OSX and PIL-box

[Egan Ford]

Quote:1. How are you getting the cps rates?

Code:


DISP FLOOR(.5+FILESIZE(F$&D$)/(TIME-T));"BYTES/S"

NOTE: FILESIZE is from JPC ROM

Quote:2. Would you be willing to share a copy of the backup program?

Code:


10 ON ERROR GOTO 160
20 DESTROY ALL @ OPTION BASE 1 @ I=1
30 INPUT "Source->",":HDRIVE1";S$
40 INPUT "Destination->",":MAIN";D$
50 IF CAT$(I,S$)="" THEN 140
60 F$=CAT$(I,S$)[1,8]
70 FOR J=8 TO 1 STEP -1
80 IF F$[J,J]=" " THEN F$=F$[1,J-1] ELSE 100
90 NEXT J
100 IF F$="workfile" THEN 130
110 DISP "COPY ";F$&S$;" TO ";D$
115 T=TIME
120 COPY F$&S$ TO D$
125 DISP FLOOR(.5+FILESIZE(F$&D$)/(TIME-T));"BYTES/S"
130 I=I+1 @ GOTO 50
140 DESTROY ALL @ DISP "Restore Complete." @ END
150 END
160 ! ERROR HANDLER
170 IF ERRN=255030 THEN 200
180 DISP ERRM$
190 END
200 ! FILE EXISTS
210 DISP "PURGE ";F$&D$
220 PURGE F$&D$
230 GOTO 110

Quote:3. Would you be willing to share the LOOPCAT program? Sounds useful.

Code:


430 DISP " N AID ID$"
440 I=1
445 IF DEVAID(I)<0 AND DEVID$(I)="" THEN 470
450 DISP I;DEVAID(I);DEVID$(I)
460 I=I+1 @ GOTO 445
470 END

Quote:4. Have you tried storing most of the programs in an IRAM? Then you can restore all of them using a single ROMCOPY command to restore the entire IRAM contents at once.

I just read about ROMCOPY in the IRAM thread. I have not tested or used it.