Post Reply 
(11C) Prismoidal Solver
05-25-2019, 12:30 AM (This post was last modified: 05-25-2019 03:07 AM by Gamo.)
Post: #1
(11C) Prismoidal Solver
Prismoidal formula is used in the calculation of earthwork quantities.

The "Volume" of any prismoid is equal to one-sixth its length multiplied
by the sum of the two end-areas plus four times the mid-area.

Formula Used: V = [ h(m1 + 4m2 + m3) ] ÷ 6

Where:

m1 (Base Area)
m2 (Middle Section Area)
m3 (Top Area)
h (Height)

----------------------------------
Procedure: User Mode

[A] Rectangular Prism
Height [ENTER] Length [ENTER] Width [A]

[B] Cylinder
Height [ENTER] Radius [B]

[C] Pyramid
Height [ENTER] Length [ENTER] Width [C]

[D] Sphere
Height [D]

[E] Custom Volume
Height [ENTER] Middle Area [ENTER] Top Area [ENTER] Base Area [E]

------------------------------------------------
Program:
Code:

LBL A
x
STO 1
STO 2
STO 3
X<>Y
STO 4
GTO 1
----------------
LBL B
X^2
pi
x
STO 1
STO 2
STO 3
X<>Y
STO 4
GTO 1
---------------
LBL C
STO 5
X<>Y
STO 6
2
÷
X<>Y
2
÷
x
STO 2
RCL 5
RCL 6
x
STO 1
R↓
X<>Y
STO 4
0
STO 3
GTO 1
-------------
LBL D
STO 4
2
÷
X^2
pi
x
STO 2
0
STO 1
STO 3
GTO 1
--------------
LBL E
+
X<>Y
4
x
+
x
6
÷
RTN
-------------
LBL 1
RCL 1
RCL 2
4
x
RCL 3
+
+
6
÷
RCL 4
x
RTN

----------------------------

Example: FIX 1

Volume of Pyramid:
h = 10
w = 8
l = 6

10 [ENTER] 8 [ENTER] 6 [C] display 160

----------------------------

Volume of Sphere:
r = 3 // Radius is 3 double this up become 6 (Height = 6)

6 [D] display 113.1

----------------------------

Gamo
Find all posts by this user
Quote this message in a reply
Post Reply 


Messages In This Thread
(11C) Prismoidal Solver - Gamo - 05-25-2019 12:30 AM
RE: (11C) Prismoidal Solver - PedroLeiva - 05-25-2019, 02:07 AM



User(s) browsing this thread: 1 Guest(s)