Post Reply 
(12C) Add or Subtract Fractions
09-17-2018, 05:49 AM (This post was last modified: 09-17-2018 01:18 PM by Gamo.)
Post: #1
(12C) Add or Subtract Fractions
Program to Add or Subtract Fractions
Result is simplify to lowest term and
convert to Mixed Fraction.

In the form of

a/b [+ or -] c/d = e/f

If f < e
Then get the result for Mixed Fraction of g+ h/f

Procedure:

a [ENTER] b [ENTER] c [ENTER] d [R/S]
Answer e [X<>Y] f

If Answer f < e press [R/S] --> answer display of g.000h [X<>Y] f of g+ h/f

If Answer f > e is the "Final Answer" press [R/S] and ignore any decimal display.

-----------------------------------------------------------------------------------------

Example: 8/71 + 7/8

8 [ENTER] 71 [ENTER] 7 [ENTER] 8 [R/S]

Display 561 [X<>Y] 568

Answer is 561/568 // Denominator is larger than numerator is a "Final Answer"
Press [R/S] and ignore any decimal display.

------------------------------------------------------------------

Example: 130/19 + 7/3

130 [ENTER] 19 [ENTER] 7 [ENTER] 3 [R/S]

Display 523 [X<>Y] 57

Answer is 523/57 // Denominator is less than numerator then get Mixed Fraction.

Press [R/S] Display 9.0010 [X<>Y] 57

Final Answer is 9+ 10/57

----------------------------------------------------------
Program: Add or Subtract Fractions
Code:

01 STO 4
02 Rv
03 STO 3
04 Rv
05 STO 2
06 Rv
07 STO 1
08 RCL 2
09 RCL 4
10 X≤Y
------------------------------------
11 X<>Y
12 X<>Y
13 STO 0
14 X<>Y
15 ENTER
16 ENTER
17 ENTER
18 RCL 0
19  ÷
20 FRAC
----------------------------------
21 X=0
22 GTO 26
23 Rv
24  +
25 GTO 16
26  +
27 STO 5
28 RCL 2
29  ÷
30 RCL 1
-------------------------------
31  x
32 RCL 5
33 RCL 4
34  ÷
35 RCL 3
36  x
37  +
38 STO 6
39 RCL 5
40 X≤Y
--------------------------
41 X<>Y
42 X<>Y
43  -
44 LSTx
45 X<>Y
46 X=0
47 GTO 49
48 GTO 40
49 X<>Y
50 STO 7
-------------------------------
51  1
52 X<>Y
53 X≤Y
54 GTO 62
55 RCL 5
56 RCL 7
57  ÷
58 RCL 6
59 RCL 7
60  ÷
-------------------------------
61 GTO 64
62 RCL 5
63 RCL 6
64 R/S
65 STO 0
66 X<>Y
67 X<>Y
68  ÷
69 LSTx
70 X<>Y
----------------------------
71 ENTER
72 FRAC
73 X<>Y
74 INTG
75 Rv
76  x
77 EEX
78  4
79  ÷
80 Rv
--------------------------------
81 Rv
82 Rv
83  +
84 FIX 4
85 RCL 0
86 X<>Y
87 GTO 00

Remark: Program will run fast on modern HP-12C like 12C+ and HP-12C Emulators
Gamo
Find all posts by this user
Quote this message in a reply
Post Reply 


Messages In This Thread
(12C) Add or Subtract Fractions - Gamo - 09-17-2018 05:49 AM
RE: (12C) Add or Subtract Fractions - Gamo - 09-19-2018, 07:55 AM
RE: (12C) Add or Subtract Fractions - Gamo - 09-25-2018, 02:36 AM



User(s) browsing this thread: 1 Guest(s)