arcsinc( 1-y ), for small y

[Albert Chan]

Re-phrase previous post asinc(1-y) in terms of k, with shorter constants:

\(\large asinc(k) ≈ \Large \sqrt{{12(1-k) \over 1-0.2041(1-k)\;+ \sqrt{(27.11-k)(0.0065+0.0318k)}}} \)

Free-42 code, Newton's method using above guess:

Code:

00 { 85-Byte Prgm }
01▸LBL "ASINC"
02 27.11
03 X<>Y
04 -
05 LASTX
06 STO ST Z     ; k   27.11-k   k
07 0.0318
08 ×
09 65ᴇ-4
10 +
11 ×
12 SQRT
13 1
14 STO- ST Z
15 +            ; 1+sqrt1   k-1 k
16 0.2041
17 RCL× ST Z
18 +
19 ÷
20 -12
21 ×
22 SQRT
23▸LBL 01       ; newton, f = sinx - kx
24 RCL× ST Z    ; kx    .   k   .
25 LASTX
26 STO ST Z     ; x     kx  x   k
27 SIN
28 -
29 RCL ST Y     ; x    -f   x   k
30 COS
31 RCL- ST T    ; f'   -f   x   k
32 ÷            ; e    x    k   k
33 STO+ ST Y    ; e    x'   k   k
34 X↑2
35 X<>Y
36 STO+ ST Y    ; x' x'+e^2 k   k
37 X≠Y?
38 GTO 01
39 END

Redo previous posts examples:

asinc(5280/5281) → 0.03370775880987942934821849830508089
asinc(0.99)          → 0.2453178088540252967075843126095618
asinc(5280/5380) → 0.3348901065998630063407861032211992
asinc(1/6.5)         → 2.711312910356983336479873410532187