# HP Forums

Full Version: (42s) Lagrange L1, L2 and L3 points
You're currently viewing a stripped down version of our content. View the full version with proper formatting.
Solver programs to calculate the Lagrange L1, L2 and L3 orbital points.

00 { 78-Byte Prgm }
01 LBL "L1" @ LAGRANGE L1 POINT. WATCH YOUTUBE OV1z7srUYBM
02 MVAR "μ1" @ FIRST MASS' STANDARD GRAVITATIONAL PARAMETER
03 MVAR "μ2" @ SECOND MASS' STANDARD GRAVITATIONAL PARAMETER
04 MVAR "R21" @ DISTANCE OF SECOND MASS FROM FIRST MASS
05 MVAR "RS2" @ DISTANCE OF SATELLITE FROM SECOND MASS
06 RCL "μ1"
07 RCL "R21"
08 RCL- "RS2" @ ADDITION IN CASE OF L2
09 X↑2
10 ÷
11 RCL "μ2"
12 RCL "RS2"
13 X↑2
14 ÷
15 - @ ADDITION IN CASE OF L2
16 RCL "μ1"
17 RCL "R21"
18 X↑2
19 ÷
20 1
21 RCL "RS2"
22 RCL÷ "R21"
23 - @ ADDITION IN CASE OF L2
24 ×
25 -
26 END

00 { 78-Byte Prgm }
01 LBL "L2" @ LAGRANGE L2 POINT. WATCH YOUTUBE OV1z7srUYBM FOR L1 EXPLANATION
02 MVAR "μ1" @ FIRST MASS' STANDARD GRAVITATIONAL PARAMETER
03 MVAR "μ2" @ SECOND MASS' STANDARD GRAVITATIONAL PARAMETER
04 MVAR "R21" @ DISTANCE OF SECOND MASS FROM FIRST MASS
05 MVAR "RS2" @ DISTANCE OF SATELLITE FROM SECOND MASS
06 RCL "μ1"
07 RCL "R21"
08 RCL+ "RS2" @ SUBSTRACTION IN CASE OF L1
09 X↑2
10 ÷
11 RCL "μ2"
12 RCL "RS2"
13 X↑2
14 ÷
15 + @ SUBSTRACTION IN CASE OF L1
16 RCL "μ1"
17 RCL "R21"
18 X↑2
19 ÷
20 1
21 RCL "RS2"
22 RCL÷ "R21"
23 + @ SUBSTRACTION IN CASE OF L1
24 ×
25 -
26 END

00 { 72-Byte Prgm }
01 LBL "L3" @ LAGRANGE L3 POINT. WATCH YOUTUBE OV1z7srUYBM FOR L1 EXPLANATION
02 MVAR "μ1" @ FIRST MASS' STANDARD GRAVITATIONAL PARAMETER
03 MVAR "μ2" @ SECOND MASS' STANDARD GRAVITATIONAL PARAMETER
04 MVAR "R21" @ DISTANCE OF SECOND MASS FROM FIRST MASS
05 MVAR "RS1" @ DISTANCE OF SATELLITE FROM FIRST MASS
06 RCL "μ1"
07 RCL "RS1"
08 X↑2
09 ÷
10 RCL "μ2"
11 RCL "RS1"
12 RCL+ "R21
13 X↑2
14 ÷
15 +
16 RCL "μ1"
17 RCL "RS1"
18 ×
19 RCL "R21"
20 3
21 Y↑X
22 ÷
23 -
24 END
Reference URL's
• HP Forums: https://www.hpmuseum.org/forum/index.php
• :