The Museum of HP Calculators

# Accumulated Interest/Remaining Balance for the HP-67

This program is Copyright © 1976 by Hewlett-Packard and is used here by permission. This program was originally published in the HP-67 Business Decisions Pac.

This program is supplied without representation or warranty of any kind. Hewlett-Packard Company and The Museum of HP Calculators therefore assume no responsibility and shall have no liability, consequential or otherwise, of any kind arising from the use of this program material or any part thereof.

 Accumulated Interest/Remaining Balance Shift ->Sched P? Label J,K i PMT PV ->INT;RB Key A B C D E

## Overview

This program finds both the total interest paid over a specified number of payment periods and the remaining balance at the end of the last specified period, given the periodic interest rate, periodic payment amount, loan amount, and the beginning and ending payment numbers for the time span being considered. The payments associated with both the beginning (J) and the ending (K) payment period are included in the calculation.

The program can be used for loans with a balloon payment as well as loans arranged to be fully amortized provided two cautions are observed. First, the balloon payment of the loan must be at the same time as, and in addition to the last payment. Second, care should be taken not to enter a value for K that is after the last payment since the program has no way of knowing the term of the loan.

An option is available to output the amortization schedule between payments J and K (f A).

Pressing f E sets and clears the print flag. Successive use of f E will alternately display 1.00 and 0.00, indicating that the print/pause mode is on or off respectively.

The data generated is valid for loans that have a balloon payment, as well as those that are arranged to be fully amortized. For loans with a balloon payment, the remaining balance of the last payment period is the balloon payment due in addition to the last periodic payment.

For loans scheduled to be fully amortized, the remaining balance after the last payment period may be slightly more or less than zero. This is because the program assumes that all payments are equal to the value entered for PMT. In fact for most loans, the last payment is slightly more or less than the rest.

The calculator performs all internal calculations to ten digits. If the user wishes to round the schedule to dollars and cents, the following sequence may be used:

1. Press GTO . 113
2. Switch to PRGM mode.
3. Press RND
4. Switch back to RUN mode.

## Instructions

 Step Instructions Input Data/Units Keys Output Data/Units 1 Load side 1 and side 2. 2 Optional: Select print/pause mode for amortization schedule. f E 1.00 or 0.00 3 Key in Starting period number J A J Ending period number K A K Periodic interest rate i (%) B i (%) Periodic payment amount PMT C PMT Initial loan amount PV D PV 4 Compute the total interest paid between periods J and K inclusive, and the remaining balance at the end of period K. E INT R/S BAL OR 5 Generate the amortization schedule between payments J and K inclusive. If the print/pause mode is on (1.00), the results are printed automatically. f A J 6 Calculate amount paid to interest for period J. R/S PMT to INT 7 Calculate amount paid to principal for period J. R/S PMT to PRIN 8 Calculate remaining balance at the end of period J. R/S BAL 9 Calculate total interest paid between periods J thru K inclusive. R/S TOT INT 10 Increment J for next period. R/S J+1 If J <= K, go to step 6 for next period's values. Otherwise, stop. 11 For a new case, go to step 2 and change appropriate input values.

## Example 1

A mortgage is arranged such that the first payment is made at the end of October, 1975 (i.e., October is payment period 1). It is a \$20,000 loan at 9%, with monthly payments of \$167.84. What is the accumulated interest for 1975 (periods 1-3) and 1976 (periods 4-15) and what would the remaining balance be at the end of each year?

```Keystrokes                     Outputs
1 A 3 A 9 ENTER 12 ÷ B
167.84 C 20000 D E              449.60 (interest paid
in 1975)
R/S                           19946.08 (remaining balance at
the end of 1975)
4 A 15 A E                     1785.89 (interest paid
in 1976)
R/S                           19717.88 (remaining balance at
the end of 1976)
```

## Example 2

Generate an amortization schedule for the first two payments of a \$30,000, 7% mortgage having monthly payments of \$200. Then jump ahead and generate the data for the 36th payment.

```Keystrokes                     Outputs
1 A 2 A 7 ENTER 12 ÷ B
200 C 30000 D f A                  1.00 (starting 1st period)
R/S                              175.00 (payment to interest)
R/S                               25.00 (payment to principal)
R/S                            29975.00 (remaining balance)
R/S                              175.00 (total interest to
date)
R/S                                2.00 (starting 2nd period)
R/S                              174.85 (payment to interest)
R/S                               25.15 (payment to principal)
R/S                            29949.85 (remaining balance)
R/S                              349.85 (total interest to date)
```

Now let's skip ahead to the 36th payment period.

```36 A A f A                        36.00 (starting 36th period)
R/S                              169.36 (payment to interest)
R/S                               30.64 (payment to principal)
R/S                            29001.75 (remaining balance)
R/S                             6201.75 (total interest to date)
```

## The Program

```LINE  KEYS
001  *LBL A
002   RCL 0
003   STO 7     J->R7
004   X<>Y      K->R0
005   STO 0
006   RTN
007  *LBL B
008   EEX
009   2         i/100->R1
010   ÷
011   STO 1
012   LST X
013   x
014   RTN
015  *LBL C
016   STO 2     PMT->R2
017   RTN
018  *LBL D
019   STO 3
020   RTN       PV->R3
021  *LBL E
022   RCL 0
023   RCL 7
024   X<=Y?
025   GTO 0
026   STO 0
027   roll dn
028   STO 7
029  *LBL 0
030   1
031   RCL 1
032   +         (1+i/100)->R8
033   STO 8
034   RCL 0
035   GSB 1     BALk->R4
036   STO 4
037   RCL 8
038   RCL 7
039   1
040   -
041   GSB 1     -BALj-1
042   CHS
043   RCL 4
044   +         BALk - BALj-1->R6
045   STO 6
046   RCL 0
047   RCL 7
048   -
049   1
050   +
051   RCL 2
052   x
053   +
054   RTN       INTj-k
055   RCL 4     BALk
056   R/S
057  *LBL a
058   RCL 7
059   F0?
060   PRT SPC
061   GSB 9     J
062   1
063   RCL 1
064   +
065   STO 8
066   RCL 7
067   GSB 1
068   STO 4
069   RCL 8
070   RCL 7
071   1
072   -
073   GSB 1
074   RCL 4
075   -
076   STO 6
077   RCL 2
078   X<>Y
079   -         INTj
080   GSB 9
081   RCL 6
082   GSB 9     PRINCj
083   RCL 4
084   GSB 9     RBALj
085   RCL 7
086   RCL 2
087   x
088   RCL 3
089   RCL 4
090   -
091   -
092   GSB 9     TOT INT
093   1
094   STO + 7
095   RCL 0
096   RCL 7
097   X<=Y?     J<=K?
098   GTO a
099   RTN
100  *LBL 1
101   CHS
102   YX
103   STO 5
104   1
105   -
106   RCL 1
107   ÷
108   RCL 2
109   x
110   RCL 3
111   +
112   RCL 5
113   ÷         RND may be inserted here.
114   RTN
115  *LBL e
116   F0?
117   GTO 2     Print mode option.
118   SF 0
119   1
120   RTN
121  *LBL 2
122   0
123   CF 0
124   RTN
125  *LBL 9
126   F0?
127   GTO 3
128   R/S
129   RTN
130  *LBL 3
131   PRTX
132   RTN
133   R/S
```

```R0  K
R1  i/100
R2  PMT
R3  PV
R4  Used
R5  Used
R6  Used
R7  J
R8  1+i/100
```