The Museum of HP Calculators


Ultimate Alarm Clock for the HP-41

This program is by Geir Isene and is used here by permission.

This program is supplied without representation or warranty of any kind. Geir Isene and The Museum of HP Calculators therefore assume no responsibility and shall have no liability, consequential or otherwise, of any kind arising from the use of this program material or any part thereof.

Overview

The program that turns your HP-41CX (or 41C/CV with a time module) into the ultimate alarm clock. It gives your belowed calculator all the features of a very advanced alarm clock. It even lets you hear the time so you don't have to turn on the light to see what time it is :)

I have a passion for old Hewlett Packard calculators. I love to program these little beauties. Now and then I even make a very usefull program such as this one. I have never seen an alarm clock that can do everything I wanted it to. So, I decided to program my HP-41CX to serve my needs. It has the features I want:

    * Set the alarm to a specific time

    * Set the alarm to a certain time from now

    * Set the alarm to a preset time from now

    * Move the alarm a  hour into the future

    * Move the alarm a 1 hour into the future

    * Hold the alarm clock until you restart it

    * When the alarm goes off, stop it by pressing any key

    * When the alarm goes off, snooze by  hour

    * When the alarm goes off, snooze by 1 hour

    * Clear the next alarm

    * Clear all alarms

    * Hear the time!

    * Hear when the alarm is supposed to go off!

    * Hear how much time left untill the alarm goes off!
More precisely, here is the key mapping:
LABEL   DESCRIPTION


ALMS    Starts the program. Shows some of the mapping for the top keys so
        that you don't have to remember this list and then stops.
        Pressing R/S will give you the running clock. Pressing R/S again
        will give you the alarm catalog. Another R/S gives you the version
        number of the UAC. Then pressing R/S will return you to the
        mapping (menu).
ALM     Set an alarm. Just enter the time and execute ALM. If the time
        greater than the present time, it will set the alarm for that time
        later today. If the time is less than the present time, it will
        set the alarm time to that time tomorrow.
ALM+    Enter the time from now you want the alarm to go off and execute
        ALM+.
LBL A   Set the alarm 8:10h into the future (to change this preset time,
        change line 11 in the program).
LBL a   Set the alarm 9:00h into the future (alter by changing line 18)
LBL B   Postpone the alarm by  hour (both if the alarm is sounding or if
        it has not yet sounded). If the "wake-uo"-type alarms have been
        cleared (by pressing "C" or "c"), it will set an alarm  hour from
        now.
LBL b   As above, but postpone the alarm by the amount you enter.
LBL C   Delete "wake-up"-type alarms.
LBL c   Delete all alarms.
LBL D   Hear how long it is until the alarm goes off. Same principle as
        with SCLK - one low beep per 6 hours, then one high beep per hour,
        then one low beep per quarter.
LBL d   Hear when the alarm is supposed to go off. Same principle as with
        LBL D.
SCLK    Hear the time. First it sounds 1-4 low beeps signaling
(LBL E) which sector of the day the time is within: 0:00-05:59, 06:00-11:59,
        12:00-17:59 or 18:00-23:59. Then 1-6 beeps signaling the number of
        hours within the sector, then 1-4 beeps signaling which quarter it
        is within the hour.
LBL e   "Hold" the alarm until you press R/S to let it continue again.
        This makes it possible to wake up in the middel of the night with
        a brilliant idea that you want to write down. Press "e" to hold
        the alarm until you are ready to return to bed. Teh press R/S and
        you still get your usual hours of beauty sleep.
When the alarm goes off, press any key to stop it. If you then press R/S, it will snooze for 10 minutes.

The UAC gives you sound feedback for all the functions. This is done so that you know if you pressed the right button in the dark.

LICENSE

This software is copyright Geir Isene 2005. It is released with no warraties under the GNU General Public License v. 2.

Program

  1 *LBL'ALMS
  2 *LBL 01
  3  '8,9 .5,+ c A T
  4  AVIEW
  5  STOP
  6  CLOCK
  7  ALMCAT
  8  STOP
  9  'V. 0.5.2
 10  AVIEW
 11  STOP
 12  GTO 01
 13 *LBL A
 14  TONE 8
 15  SF 06
 16  8,1
 17  XEQ 30
 18  GTO 02
 19 *LBL a
 20  TONE 8
 21  TONE 8
 22  SF 06
 23  9
 24  XEQ 30
 25  GTO 02
 26 *LBL B
 27  ,3
 28 *LBL b
 29  TIME
 30  RCL 00
 31  X#0?
 32  X<>Y
 33  RDN
 34  XEQ 30
 35  HMS+
 36  SF 06
 37  GTO 03
 38 *LBL C
 39  0
 40  STO 00
 41 *LBL 30
 42  SF 25
 43  '^^A+
 44  CLALMA
 45  SF 25
 46  'A+
 47  CLALMA
 48  TONE 2
 49  RTN
 50  GTO 01
 51 *LBL c
 52  0
 53  STO 00
 54  CLRALMS
 55  TONE 2
 56  TONE 2
 57  RTN
 58  GTO 01
 59 *LBL D
 60  RCL 00
 61  TIME
 62  HMS-
 63  X>0?
 64  GTO 10
 65  24
 66  HMS+
 67  GTO 10
 68 *LBL d
 69  RCL 00
 70  GTO 10
 71 *LBL'SCLK
 72 *LBL E
 73  TIME
 74  LBL 10
 75  STO 01
 76  6
 77  /
 78  INT
 79  1
 80  +
 81 *LBL 12
 82  TONE 4
 83  DSE X
 84  GTO 12
 85  RCL 01
 86  INT
 87  6
 88  /
 89  FRC
 90  6
 91  *
 92  INT
 93  1
 94  +
 95 *LBL 13
 96  TONE 9
 97  DSE X
 98  GTO 13
 99  RCL 01
100  FRC
101  100
102  *
103  15
104  /
105  INT
106  1
107  +
108 *LBL 14
109  TONE 4
110  DSE X
111  GTO 14
112  RCL 01
113  PSE
114  PSE
115  PSE
116  OFF
117  GTO 01
118 *LBL'ALM+
119 *LBL 02
120  TIME
121  HMS+
122 *LBL'ALM
123  LBL 03
124  24
125  -
126  X>0?
127  GTO 15
128  24
129  +
130  LBL 15
131  STO 00
132  '^^A+
133  TIME
134  X<>Y
135  X>Y?
136  SF 05
137  CLST
138  DATE
139  FC? 05
140  1
141  FC?C 05
142  DATE+
143  RCL 00
144  XYZALM
145  TONE 9
146  FS?C 06
147  RTN
148  PSE
149  PSE
150  OFF 
151  LBL e
152  TIME
153  STO 01
154  'HOLD
155  AVIEW
156  STOP
157  TIME
158  RCL 01
159  HMS-
160  RCL 00
161  HMS+
162  SF 06
163  GTO 03
164 *LBL'A+
165  CLST 
166  'A+ 
167  DATE
168  TIME
169  ,001
170  HMS+
171  XYZALM
172  STOP
173  .1
174  GTO 02
175  END

Go back to the HP-41 software library
Go back to the general software library
Go back to the main exhibit hall