The Museum of HP Calculators


Binary Stars for the HP-41

This program is Copyright © 2005 by Jean-Marc Baillard and is used here by permission.

This program is supplied without representation or warranty of any kind. Jean-Marc Baillard and The Museum of HP Calculators therefore assume no responsibility and shall have no liability, consequential or otherwise, of any kind arising from the use of this program material or any part thereof.

Overview

-This program calculates the polar coordinates ( r ; µ ) of a binary star  ( S1 ; S2 )
 and the eccentricity e' of the apparent orbit, as seen from the Earth.
 

                   North
                       |
            S2       |
              \        |
                \  µ  |
               r  \    |                                     r  =  the angular distance = S1S2
                    \  |                                     µ  =  the position angle = ( S1N ; S2N )
                      \|
                      S1
 

Program Listing
 

Data Registers:       When the program stops,   R00 = e' =  eccentricity of the apparent orbit

    -Registers R08 & R09 are used for temporary data storage.          Registers R01 thru R07 are to be initialized before executing "BSTAR"

                               R01 = P = period of revolution ( expressed in years )
                               R02 = T = time of perihelion passage ( given as a year and decimals )
                               R03 = e = eccentricity
                               R04 = a = semimajor axis ( in arcseconds )
                               R05 = i  = inclination of the orbit
                               R06 = OMEGA = position angle of the ascending node
                               R07 = omega = longitude of the periastron.

Flags: /
Subroutines: /
 

  01  LBL "BSTAR"
  02  DEG
  03  STO 00
  04  RCL 03
  05  RCL 07
  06  COS
  07  *
  08  X^2
  09  STO 08
  10  RCL 05
  11  COS
  12  X^2
  13  ST* Y
  14  -
  15  X<> 08
  16  RCL 03
  17  X^2
  18  -
  19  1
  20  +
  21  RCL 05
  22  COS
  23  RCL 07
  24  RCL 03
  25  P-R
  26  *
  27  *
  28  ST+ X
  29  X^2
  30  RCL 08
  31  ST- Z
  32  R^
  33  +
  34  X^2
  35  +
  36  SQRT
  37  ENTER^
  38  ST+ Y
  39  R^
  40  +
  41  /
  42  SQRT
  43  X<> 00
  44  RCL 02
  45  -
  46  360
  47  *
  48  RCL 01
  49  /
  50  STO 08
  51  STO 09
  52  LBL 01                      lines 52 to 66 solve Kepler's equation
  53  RCL 09                     the iterations stop when the difference between 2 successive approximations is smaller than 0.001°  ( line 64 )
  54  ENTER^
  55  SIN
  56  RCL 03
  57  R-D
  58  *
  59  RCL 08
  60  +
  61  STO 09
  62  -
  63  ABS
  64   E-3
  65  X<=Y?
  66  GTO 01
  67  RCL 09
  68  2
  69  /
  70  1
  71  RCL 03
  72  ST+ Y
  73  ASIN
  74  COS
  75  /
  76  P-R
  77  LASTX
  78  /
  79  R-P
  80  X<>Y
  81  ST+ X
  82  RCL 07
  83  +
  84  1
  85  P-R
  86  STO 08
  87  X<>Y
  88  RCL 05
  89  COS
  90  *
  91  X<>Y
  92  R-P
  93  CLX
  94  RCL 06
  95  +
  96  1
  97  RCL 09
  98  COS
  99  RCL 03
100  *
101  -
102  RCL 04
103  *
104  RCL 08
105  *
106  RCL Y
107  RCL 06
108  -
109  COS
110  /
111  END

( 135 bytes / SIZE 010 )
 
 
      STACK        INPUTS      OUTPUTS
           Y            /            µ
           X       YYYY.yy             r

 

Example:   The elements of  Gamma Virginis are:         P = 168.68 years              a = 3.697"             OMEGA =  36.
                                                                                    T = 2005.13                      i = 148.0°                 omega = 256.
                                                                                    e = 0.885

            -Calculate  r  and  µ  for the epoch  2010.25    ( ~ 2010/04/01 )

-Store these 7 numbers in registers R01 thru R07  ( in the order  P ,  T ,  e  ,  a  ,  i  ,  OMEGA  ,  omega  )

-Then,     2010.25  XEQ "BSTAR"  >>>>  r =  1.544"         ( in 33 seconds )
                                                     X<>Y   µ =  19.66°         ( and the apparent eccentricity  e' = 0.844 in R00 )

Notes:    -If you don't need to compute the apparent eccentricity e' , delete lines 03 to 43.
               -Execution time may tend to infinity as e tends to 1.

-Here are the elements of a few binary stars. Right Ascensions and declinations are referred to J2000
-m1 & m2 are the magnitudes.
 
 
   STARS   Right Asc        Decl        m1        m2         P         T         e         a         i   OMEGA    omega
   eta Cas   0h49m05s  +57°49'00"        3.7        7.5       480.0    1889.6      0.497     11.994       34.8     278.4    268.6
  alpha Psc   2h02m03s   +2°45'49"        4.3        5.3     933.050   2098.643      0.696      4.000      120.9       23.3    225.4
  alpha For   3h12m04s  -28°59'21"        3.8        7.0       269.0    1947.0      0.730      4.000        81.0     117.0      43.0
    Sirius   6h45m09s  -16°42'58"      -1.        8.4      50.090   1894.130      0.592      7.500      136.5       44.6    147.3
   Castor   7h34m36s  +31°53'19"        2.0        2.9     467.000   1958.000      0.343      6.805      114.5       41.3    249.5
  Procyon   7h39m18s   +5°13'39"        0.4      10.8      40.650   1927.600      0.400      4.548       35.7     284.3    269.8
 gamma Leo 10h19m58s  +19°50'31"        2.6        3.8     618.557   1743.320      0.843      2.505       36.4     143.2    162.5
   xi Uma 11h18m11s  +31°31'45"        4.3        4.8       59.840   1995.050      0.412      2.533      121.2     100.9    126.8
 gamma Vir 12h41m40s   -1°26'58"        3.6        3.7     168.680   2005.130      0.885      3.697      148.0      36.9    256.5
  zeta Uma 13h23m55s  +54°55'31"        1.6        2.1       36.5    1994.8        0.6       0.80        93.0      32.0    287.0
   xi  Boo 14h51m24s  +19°06'02"        4.8        6.9     151.505   1909.361      0.512      4.904      140.0     168.1     23.9
  eta CrB 15h23m12s  +30°17'18"        5.0        5.3      41.585   1933.721      0.262      0.868       59.0     203.2     38.4
 sigma CrB 16h14m42s  +33°51'31"        5.7        6.7     888.989   1826.949      0.761      5.927       31.8      16.9     72.2
  zeta Her 16h41m17s  +31°36'07"        2.8        5.5       34.45    1967.7       0.46       1.33      131.0      50.0    111.0
   70 Oph 18h05m27s   +2°30'09"        4.3        6.0       88.38   1895.94      0.499      4.554      121.2     302.1     14.0
gamma CrA 19h06m25s  -37°03'46"        4.2        4.3     121.760   2000.640      0.320      1.896      149.6      50.3    349.0
  beta Cyg 19h30m43s  +27°57'35"        3.2        5.3      96.840   2010.270      0.719      0.586      118.0      98.8     77.2
   61 Cyg 21h06m54s  +38°44'58"        5.6        6.3     722.000   1689.700      0.401     24.650       51.8     172.3    158.0
  zeta Aqr 22h28m50s   -0°01'12"        3.7        3.9      587.18    1973.39      0.396      3.847      138.2     129.8    255.9

 
 

References:        Jean Meeus , "Astronomical Algorithms" - Willmann-Bell  -  ISBN 0-943396-35-2
                             Washington Double Star Catalogue.

Go back to the HP-41 software library
Go back to the general software library
Go back to the main exhibit hall