The Museum of HP Calculators

# Exponential Growth or Decay for the HP-33E/C

This program is Copyright © 1978 by Hewlett-Packard and is used here by permission. This program was originally published in "HP-33E Student Engineering Applications".

This program is supplied without representation or warranty of any kind. Hewlett-Packard Company and The Museum of HP Calculators therefore assume no responsibility and shall have no liability, consequential or otherwise, of any kind arising from the use of this program material or any part thereof.

## Overview

Many growth or decay phenomena encountered in science and engineering obey an exponential law of the general form:

Xt = Xss - (Xss - X0)e-t/K

where:
Xt = Value at any time, t, (i.e., the instantaneous value)
Xss = Steady state value (i.e., at t = infinity)
X0 = Initial Value (i.e., at t = 0)
t = Elapsed time (time after t = 0)
K= Exponential time-constant for specific phenomena

This program provides interchangeable solutions for any one of the four variables Xt, Xss, X0, or t provided three variables and K are known.

## Instructions

 Step Instructions Input Data/Units Keys Output Data/Units 1 Enter program 2 Store time constant K STO 4 3 Store variables: Initial value X0 STO 0 Instantaneous value Xt STO 1 Steady state value Xss STO 2 Elapsed time t STO 3 (Store any 3 of the 4 variables) 4 To Calculate: X0, Initial value GSB 21 X0 Xt, Instantaneous value GSB 01 Xt Xss, Steady state value GSB 09 Xss t, Elapsed time GSB 29 t 5 For a new case go to step 2.

## Example 1

Given a 5uF capacitor in series with a 1 megohm resistor. 1.5 seconds after the circuit is completed 125 volts are measured across R. To what voltage was the capacitor originally charged?

Note: K = the RC time-constant, and the voltage at t = infinity is zero.

```Keystrokes         Display
5 EEX CHS 6
ENTER EEX 6
x STO 4
125 STO 1
0 STO 2
1.5 STO 3
GSB 21             168.7324    (volts)
```

## Example 2

A cobalt 60 source (half life = 5.26 years) had an activity of 3.54 curies when purchased 8.5 years ago. What is its present activity?

Note: Activity at t = infinity will be zero, K = half life/ln 2.

```Keystrokes         Display
5.26 ENTER
2 f LN ÷
STO 4
3.54 STO 0
0 STO 2
8.5 STO 3
GSB 01             1.1549   (curies)
```

## The Program

```LINE    CODE    KEYS
00             f CLEAR PRGM
01     24  0   RCL 0
02     24  2   RCL 2
03        41   -
04     12 40   GSB 40
05        71   ÷
06     24  2   RCL 2
07        51   +
08     13 00   GTO 00
09     12 40   GSB 40
10        31   ENTER
11        31   ENTER
12     24  1   RCL 1
13        61   x
14     24  0   RCL 0
15        41   -
16        21   x<>y
17         1   1
18        41   -
19        71   ÷
20     13 00   GTO 00
21     12 40   GSB 40
22     24  1   RCL 1
23     24  2   RCL 2
24        41   -
25        61   x
26     24  2   RCL 2
27        51   +
28     13 00   GTO 00
29     24  0   RCL 0
30     24  2   RCL 2
31        41   -
32     24  1   RCL 1
33     24  2   RCL 2
34        41   -
35        71   ÷
36     14  1   f LN
37     24  4   RCL 4
38        61   x
39     13 00   GTO 00
40     24  3   RCL 3
41     24  4   RCL 4
42        71   ÷
43     15  1   g ex
44     15 12   g RTN
```

## Register Use

```R0  X0
R1  Xt
R2  Xss
R3  t
R4  K
```