Hi, very good solutions !
The 2nd problem ( regular tetrahedron ) may be solved in the same ways:
1°) Using the coordinates of the 5 points leads to a 4x4 non-linear system.
2°) We can also write that the sum of the volumes of the 4 tetrahedrons
MABC + MBCD + MACD + MABD = the volume of ABCD ( with Francesca's formula )
3°) A 3rd approach is: Sum of the 4 trihedral angles
MABC + MBCD + MACD + MABD = 720°
-But there is a "magic" formula that solves both problems and probably more:
If ABC is an equilateral triangle and AM = a , BM = b , CM = c
3(a^4+b^4+c^4+x^4) = (a^2+b^2+c^2+x^2)^2
-This can be proved using the coordinates of the 4 points, like Gerson's solution.
If ABCD is a regular tetrahedron and AM = a , BM = b , CM = c , DM = d
4(a^4+b^4+c^4+d^4+x^4) = (a^2+b^2+c^2+d^2+x^2)^2
-I must say I have not proved this formula but it would be surprising if it were wrong !
-Whence the conjecture:
If A1 A2 ... An is a regular simplex ( edge length = x )
and MA1 = a1 , MA2 = a2 , ........ , MAn = an
n [ (a1)^4 + ........ + (an)^4 + x^4 ] = [ (a1)^2 + ......... + (an)^2 + x^2 ]^2
-It works at least with n = 3 and n = 4
-So we just have to solve a quadratic equation to find x^2 !
-Here is an HP41-program:
01 LBL "WST"
02 RCL 00
03 0
04 ENTER^
05 LBL 01
06 RCL IND Z
07 X^2
08 ST+ Z
09 X^2
10 +
11 DSE Z
12 GTO 01
13 R^
14 RCL 00
15 -
16 *
17 X<>Y
18 X^2
19 +
20 RCL 00
21 *
22 SQRT
23 ST+ Z
24 -
25 RCL 00
26 1
27 -
28 ST/ Z
29 /
30 SQRT
31 X<>Y
32 SQRT
33 END ( 46 bytes )
-Store n in R00 , a1 in R01 , ..... , an in Rnn and XEQ "WST"
1°) In the 1st problem it yields x = 112 X<>Y x = 16.09347694
-The first value corresponds to a point inside the equilateral triangle
-The second value corresponds to a point outside the triangle.
2°) In the 2nd problem it yields x = 105 X<>Y x = 26.85144316
-The first value corresponds to a point inside the regular tetrahedron
-The second value corresponds to a point outside the tetrahedron.
-Here, 112 and 105 are ( exact ) integers
Perhaps will you find a simple proof for the general case ?
Best regards,
Jean-Marc.