Re: Need help with HP82164A HP-IL/RS232 Interface Message #11 Posted by Egan Ford on 3 Nov 2009, 11:54 a.m., in response to message #8 by Ilyas B.
Quote:
Could you advice another terminal program?
I did not have a lot of time, but this worked for me.
Create the following programs:
T2S:
10 REMOTE @ OUTPUT :HP82164A ;"LI5;C0" @ LOCAL
20 ON ERROR GOTO 120
30 DESTROY ALL
40 DIM A$[100]
50 INPUT "FILENAME:";F$
60 TRANSFORM F$ INTO TEXT TMPFILE
70 ASSIGN #1 TO TMPFILE
80 READ #1;A$
90 DISP A$
100 OUTPUT :HP82164A ;A$
110 GOTO 80
120 OUTPUT :HP82164A ;"EOF"
130 PURGE TMPFILE
140 END
S2T:
10 REMOTE @ OUTPUT :HP82164A ;"LI5;C0;SL2" @ LOCAL
20 DESTROY ALL
30 DIM A$[100]
40 INPUT "FILENAME:";F$
50 PURGE F$
60 CREATE TEXT F$
70 ASSIGN #1 TO F$
80 ENTER :HP82164A ;A$
90 IF A$="EOF" THEN CLEAR :HP82164A @ GOTO 130
100 DISP A$
110 PRINT #1;A$
120 GOTO 80
130 ASSIGN #1 TO * @ TRANSFORM F$ INTO BASIC
140 END
Connect the 82164 to your PC with a standard null modem cable, do not use the custom cable (did not work for me).
Launch Hyperterminal, setup with 9600 BPS, 8N1, Hardware Flow, and terminate lines with LF (Hint: Properties/Settings/ASCII Setup/Send line ends with line feeds).
To backup a BASIC program run T2S, from HT just cut and paste the output into notepad.
To restore a BASIC program run S2T, from notepad cut and pasted into HT. NOTE: Your input must end with the line EOF<cr>. If not, just type EOF<cr> in HT.
There is a minor issue I did not have time to resolve, so after each transfer power off your 71B, press reset on the 82164, power 71B back on.
Good luck.
P.S. Sell your 82164 and get a PIL-Box (USB to HP-IL). It will be easier.
Edited: 3 Nov 2009, 12:01 p.m.
|