HP Forums
(HP 41 CV/CX, DM41) Date of Easter sunday - Printable Version

+- HP Forums (https://www.hpmuseum.org/forum)
+-- Forum: HP Software Libraries (/forum-10.html)
+--- Forum: HP-41C Software Library (/forum-11.html)
+--- Thread: (HP 41 CV/CX, DM41) Date of Easter sunday (/thread-21677.html)

(HP 41 CV/CX, DM41) Date of Easter sunday - rawi - 04-30-2024 01:39 PM

Find the Date of Easter Sunday for any year between 1583 and 9999.

I was somewhat surprised not to find an existing program to do this. The only program I found is finding more religious days and is longer. So I made the following solution. Enjoy!

Application:
XEQ Alpha EASTER Alpha -> YEAR? -> Put in year, e.g. 2024 R/S -> 3103.2024
Interpretation: Easter Sunday in 2024 was 31st of March.
Registers used: 00-12
Source for algorithm:
Duffet-Smith, P.: Practical astronomy with your calculator, 3rd ed., Cambridge 1979, p. 3

Code:
LBL ‘EASTER
    ‘YEAR?
    PROMPT
    STO 00
    19 
    MOD
    STO 01
    RCL 00
    100
10  MOD
    STO 03
    RCL 00
    100
    /
    INT
    STO 02
    4
    /    
    INT
20  STO 04
    RCL 02
    4
    MOD
    STO 05
    RCL 02
    8
    +
    25
    /
30  INT
    STO 06
    CHS
    RCL 02
    +
    1
    +
    3
    /
    INT
40  STO 07
    CHS
    RCL 01
    19
    *
    +
    RCL 02
    +
    RCL 04
    -
50  15
    +
    30
    MOD
    STO 08
    RCL 03
    4
    /
    INT
    STO 09
60  RCL 03
    4
    MOD
    STO 10
    CHS
    X<>Y
    RCL 05
    +
    2
    *
70  +
    32
    +
    RCL 08
    -
    7
    MOD
    STO 11
    22
    *
80  RCL 08
    11
    *
    +
    RCL 01
    +
    451
    /
    INT
    STO 12
90  7
    *
    CHS
    RCL 08
    +
    RCL 11
    +
    114
    +
    ENTER
100 ENTER
    31
    /
    INT
     X<>Y
    31
    MOD
    1
    +
    100
110 *
    +
    RCL 00
    10000
    /
    +
    FIX 4
    RTN
118 END


RE: (HP 41 CV/CX, DM41) Date of Easter sunday - HP67 - 05-01-2024 08:48 AM

https://en.wikibooks.org/wiki/Mathematics_of_the_Jewish_Calendar/Gauss'_Formula_for_the_Date_of_Pesach

I seem to remember Gauss published one for Easter, but maybe I'm wrong about that.

RE: (HP 41 CV/CX, DM41) Date of Easter sunday - Thomas Klemm - 05-01-2024 09:21 AM

(05-01-2024 08:48 AM)HP67 Wrote:  I seem to remember Gauss published one for Easter

Correct: Gaußsche Osterformel

RE: (HP 41 CV/CX, DM41) Date of Easter sunday - rawi - 05-01-2024 09:24 AM

HP 67 wrote:
Quote:I seem to remember Gauss published one for Easter, but maybe I'm wrong about that.

No, you are not wrong about that. In German wikipedia there is an article about "Gaußsche Osterformel" (Easter formula by Gauss"): https://de.wikipedia.org/wiki/Gau%C3%9Fsche_Osterformel

I did not check completely but the solution in the book I used seems to be the solution by Gauss.

RE: (HP 41 CV/CX, DM41) Date of Easter sunday - HP67 - 05-01-2024 09:38 AM

Thanks Guys Smile

RE: (HP 41 CV/CX, DM41) Date of Easter sunday - SlideRule - 05-01-2024 01:27 PM

A 'nuther approach, attached.
[attachment=13502]
BEST!
SlideRule